Kit PC World De Ampliacion De Windows 95/Kit PC World de ampliacion de Windows 95.iso/clarion/cw15/examp15.z/CDPLAYER.CLW

Text File | 1995-09-09 | 39KB | 1,160 lines

  PROGRAM

 INCLUDE('EQUATES.CLW')
 INCLUDE('KEYCODES.CLW')
 INCLUDE('CWWINAPI.INC')

MaximumTextLength    EQUATE(60)
ActiveTimerDisplay   EQUATE(75)
InactiveTimerDisplay EQUATE(200)

Repeat_None         EQUATE(0)
Repeat_Track        EQUATE(1)
Repeat_All          EQUATE(2)

Door_Open           EQUATE(1)
Door_Closed         EQUATE(0)

CDAvailable         BYTE
CDEjectPossible     BYTE

CDPlayerReady       BYTE

CDStatus            STRING(9)
Old_CDStatus        STRING(9)
StatusChanged       LONG

CDPlaying           LONG(0)
CDPaused            LONG

StayOnTop           LONG
Old_StayOnTop       LONG

ControlPanel        LONG
Old_ControlPanel    LONG(-1)

RepeatMode          BYTE
TrackMultiplier     BYTE
NumberOfTracks      BYTE

CurrentTrack        LONG
LastTrack           LONG
NewAlbum            LONG(1)

RemainingTime       LONG

AlbumStarts         LONG
AlbumTime           LONG
TrackTime           LONG
AlbumPosition       LONG
TrackPosition       LONG
AlbumRemaining      LONG
TrackRemaining      LONG

INISettingsFound    BYTE
TrackListPointer    LONG
WindowX             LONG
WindowY             LONG
WindowHeight        LONG
WindowWIdth         LONG

PlayList            STRING(MaximumTextLength)
Old_PlayList        STRING(MaximumTextLength)
PlayLists           QUEUE,PRE
                      STRING(MaximumTextLength)
                    END

CurrentTrackText    STRING(MaximumTextLength)
PLTracks            QUEUE,PRE
PLTrackTitle          STRING(MaximumTextLength)
PLTrackNumber         LONG
                    END

AutoPlay            BYTE

TrackList           QUEUE,PRE
TrackTitle            STRING(MaximumTextLength)
                    END

PlayListArray       STRING(2),DIM(100)
PlayListText        STRING(200),OVER(PlayListArray)
PlayListItems       LONG

! Volume Structure

TrackRows           BYTE
LoopCounter         BYTE
ValueConstruct      LONG
CurrentAlbumTitle   STRING(MaximumTextLength)
CurrentAlbumArtist  STRING(MaximumTextLength)
CurrentTrackTitle   STRING(MaximumTextLength)

StatusText          STRING(40)
Old_StatusText      STRING(40)
ShortText           STRING(20)
DisplayTime         STRING(5)
CurrentDisplayType  STRING(26)

Disp_AlbumElapsed   EQUATE(1)
Disp_AlbumRemaining EQUATE(2)
Disp_AlbumTotal     EQUATE(3)
Disp_TrackElapsed   EQUATE(4)
Disp_TrackRemaining EQUATE(5)
Disp_TrackTotal     EQUATE(6)
CurrentDisplayFlag  BYTE(1)

CompactDiscID       STRING(24)
Old_CompactDiscID   STRING(24)
NewCDLoaded         BYTE

HWND_NOTOPMOST      EQUATE(0fffeh)
WM_QUERYENDSESSION  EQUATE(0011h)
WM_ENDSESSION       EQUATE(0016h)
GWL_WndProc         EQUATE(-4)

TitleRequired       BYTE
Old_TitleRequired   BYTE

CDPlayerWindow      LONG
WindowCurrentX      LONG
WindowCurrentY      LONG

    MAP
      AppWindowProc(USHORT,USHORT,SHORT,LONG),LONG,PASCAL
      CD_PLAYER
      MCIStatus(<STRING>),STRING,PROC
      TranslateMFSTime(STRING),LONG
      FixDisplayTime(LONG),STRING
      SelectTrack(LONG,<LONG>)
      StopPlayer
      Pauseplayer
      EditPlayList,LONG
      EditPlayListTitle(STRING),STRING
      SavePlayerStatus
      AboutCDPlayer
      INCLUDE('CWWinAPI.CLW')
    END

  CODE
  CD_Player

CD_PLAYER     PROCEDURE
CDPlayWin WINDOW('Audio CD Player'),AT(,,135,229),FONT('MS Sans Serif',8,,FONT:regular),IMM,ICON('CD.ICO'), |
         SYSTEM,RESIZE,AUTO,GRAY
       MENUBAR
         MENU('&File'),USE(?File)
           ITEM('E&xit'),USE(?FileExit),STD(STD:Close)
         END
         MENU('&Options'),USE(?Options)
           ITEM('&Playlist'),USE(?OptionsPlaylist)
           ITEM('&Stay On Top'),USE(StayOnTop),CHECK
           ITEM('&Control Panel'),USE(ControlPanel),CHECK
           ITEM('&AutoPlay'),USE(AutoPlay),CHECK
         END
         MENU('&Help'),USE(?Help)
           ITEM('&About'),USE(?HelpAbout)
           ITEM('&Examples'),USE(?Examples),STD(STD:Help)
         END
       END
       TOOLBAR,AT(0,0,135,23)
         BUTTON,AT(4,1,18,18),TIP('Select the previous track'),USE(?CDSelectPrev),ICON('SMM_PREV.ICO')
         BUTTON,AT(31,1,18,18),TIP('Play the current selections'),USE(?CDplaystop),ICON('SMM_PLAY.ICO')
         BUTTON,AT(57,1,18,18),TIP('Pause the CD player'),USE(?CDpause),ICON('SMM_PAUS.ICO')
         BUTTON,AT(84,1,18,18),TIP('Select the next track'),USE(?CDSelectNext),ICON('SMM_NEXT.ICO')
         BUTTON,AT(112,1,18,18),TIP('Open the CD door'),USE(?CDDoor),ICON('SMM_CLOS.ICO')
       END
       BUTTON('&Repeat: None'),AT(2,70,64,14),TIP('Toggle the player''s repeat mode'),USE(?Repeat)
       BUTTON('&Edit Playlist'),AT(69,70,64,14),TIP('Edit the album''s playlist'),USE(?Program)
       BUTTON('1'),AT(1,44,20,10),TIP('Play a track from the ablum'),USE(?TRACK01)
       BUTTON('2'),AT(23,44,20,10),TIP('Play a track from the ablum'),USE(?TRACK02)
       BUTTON('3'),AT(45,44,20,10),TIP('Play a track from the ablum'),USE(?TRACK03)
       BUTTON('4'),AT(67,44,20,10),TIP('Play a track from the ablum'),USE(?TRACK04)
       BUTTON('5'),AT(89,44,20,10),TIP('Play a track from the ablum'),USE(?TRACK05)
       BUTTON('6'),AT(1,56,20,10),TIP('Play a track from the ablum'),USE(?TRACK06)
       BUTTON('7'),AT(23,56,20,10),TIP('Play a track from the ablum'),USE(?TRACK07)
       BUTTON('8'),AT(45,56,20,10),TIP('Play a track from the ablum'),USE(?TRACK08)
       BUTTON('9'),AT(67,56,20,10),TIP('Play a track from the ablum'),USE(?TRACK09)
       BUTTON('10'),AT(89,56,20,10),TIP('Play a track from the ablum'),USE(?TRACK10)
       BUTTON('+10'),AT(111,44,22,22),TIP('Get next set of play buttons'),USE(?TrackPlus)
       GROUP('Current Album'),AT(1,86,133,32),BOXED
         TEXT,AT(4,96,127,19),FONT(,,,FONT:bold),TIP('The album currently in the CD player'),USE(CurrentAlbumTitle), |
             DISABLE,CENTER
       END
       GROUP('Artist'),AT(1,119,133,32),BOXED
         TEXT,AT(4,129,127,19),FONT(,,,FONT:bold),TIP('The artist who produced the album'),USE(CurrentAlbumArtist), |
             DISABLE,CENTER
       END
       GROUP('Playlist'),AT(1,153,133,23),USE(?Group4),BOXED
         LIST,AT(5,162,125,10),TIP('The current playlist for this album'),USE(PlayList),FORMAT('160L@S40@'), |
             DROP(4),FROM(PlayLists)
       END
       GROUP('Current Track'),AT(1,180,133,23),BOXED
         LIST,AT(5,190,125,10),TIP('The track currently being played'),USE(CurrentTrackText),FORMAT('160L@S40@'), |
             DROP(4),FROM(PLTracks)
       END
       REGION,AT(1,6,133,36),USE(?ChangeStatus)
       GROUP('Player Status'),AT(1,1,133,41),USE(?Group1),BOXED
         STRING(@S20),AT(16,9,103,10),FONT('MS Sans Serif',8,,FONT:bold),USE(StatusText),CENTER
         STRING(@S5),AT(51,19,34,12),FONT('MS Sans Serif',10,0800000H,FONT:bold),USE(DisplayTime),CENTER
         STRING(@S26),AT(11,30,113,10),USE(CurrentDisplayType),CENTER
       END
     END

  CODE
  HELP('CW15EXAM')
  DO InitializePlayer
  OPEN(CDPlayWin)
  TARGET{Prop:Double} = True
  CDPlayerWindow = SetWindowLong(CDPlayWin{Prop:Handle},GWL_WndProc,ADDRESS(AppWindowProc))
  SYSTEM{PROP:tipdelay} = 100
  SYSTEM{PROP:tipdisplay} = 700
  CDAvailable = False
  TitleRequired = False
  IF ControlPanel
    TitleRequired = True
    IF INISettingsFound
      SETPOSITION(0,WindowX,WindowY,,23)
    ELSE
      SETPOSITION(0,,,,23)
    END
  ELSE
    IF INISettingsFound
      SETPOSITION(0,WindowX,WindowY,,)
    END
  END
  Old_ControlPanel = ControlPanel
  IF StayOnTop
    SetWindowPos(TARGET{Prop:Handle},HWND_TOPMOST,0,0,0,0,SWP_NOACTIVATE+SWP_NOMOVE+SWP_NOSIZE)
  END
  Old_StayOnTop = StayOnTop
  ACCEPT
    CASE ACCEPTED()
    OF ?StayOnTop
      IF Old_StayOnTop <> StayOnTop
        Old_StayOnTop = StayOnTop
        IF StayOnTop
          SetWindowPos(TARGET{Prop:Handle},HWND_TOPMOST,0,0,0,0,SWP_NOACTIVATE+SWP_NOMOVE+SWP_NOSIZE)
        ELSE
          SetWindowPos(TARGET{Prop:Handle},HWND_NOTOPMOST,0,0,0,0,SWP_NOACTIVATE+SWP_NOMOVE+SWP_NOSIZE)
        END
      END
    OF ?ControlPanel
      IF Old_ControlPanel <> ControlPanel
        Old_ControlPanel = ControlPanel
        IF ControlPanel
          TARGET{Prop:Height} = 23
        ELSE
          TARGET{Prop:Height} = 229
          TARGET{Prop:Text} = 'Audio CD Player'
        END
      END
    OF ?Repeat
      RepeatMode += 1
      IF RepeatMode > Repeat_All
        RepeatMode = Repeat_None
      END
      DO DisplayRepeatButton
    OF ?Program
    OROF ?OptionsPlaylist
      IF EditPlayList()
        StopPlayer
        DO DetectCDStatus
        DO InitializeNewAlbum
      END
    OF ?HelpAbout
      AboutCDPlayer
    OF ?Examples
      HELP
    OF ?ChangeStatus
      CurrentDisplayFlag += 1
      IF CurrentDisplayFlag = 7
        CurrentDisplayFlag = 1
      END
      DO GetAndDisplayTrackStatus
    OF ?CDDoor
      IF MCIStatus() = 'open'
        MCIStatus('set cdaudio door closed')
      ELSE
        MCIStatus('set cdaudio door open')
      END
    OF ?CDPlayStop
      IF NOT CDPlaying
        SelectTrack(CHOICE(?CurrentTrackText),1)
      ELSE
        StopPlayer
      END
    OF ?CDPause
      PausePlayer
    OF ?CDSelectPrev
      SelectTrack(POINTER(PLTracks)-1,CDPlaying)
    OF ?CDSelectNext
      SelectTrack(POINTER(PLTracks)+1,CDPlaying)
    OF ?TRACK01 TO ?TRACK10
      IF POINTER(PlayLists) > 1
        IF MESSAGE('This will change the order of play to the track order on the album.  Are you certain you want to do this?','Track Button Selected',Icon:Question,Button:Yes+Button:No,Button:No) = Button:No
          CYCLE
        END
        GET(PlayLists,1)
        DO LoadNewPlayList
      END
      SelectTrack((FIELD()-?TRACK01+1) + (TrackMultiplier * 10),1)
    OF ?TrackPlus
      TrackMultiplier += 1
      IF TrackMultiplier = TrackRows
        TrackMultiplier = 0
      END
      DO DisplayRandomAccessButtons
    OF ?CurrentTrackText
      SelectTrack(CHOICE(?CurrentTrackText),CDPlaying)
    OF ?PlayList
      IF Old_PlayList <> PlayList
        StopPlayer
        GET(PlayLists,CHOICE(?PlayList))
        DO LoadNewPlaylist
        IF AutoPlay
          CDPlaying = True
          SelectTrack(1,CDPlaying)
        END
      END
    END
    CASE EVENT()
    OF EVENT:OpenWindow
      DO AttemptCDInitialize
      IF NOT CDAvailable
        DO DisableAccessButtons
        DISABLE(?CDDoor)
        TARGET{Prop:Timer} = InactiveTimerDisplay
        StayOnTop = False
        IF TitleRequired
          TARGET{Prop:Text} = 'Device Not Available'
        END
        Old_TitleRequired = TitleRequired
      ELSE
        IF TitleRequired
          IF AlbumPosition <> '00:00'
            TARGET{Prop:Text} = 'CD ' & CLIP(ShortText) & '  (' & FixDisplayTime((AlbumPosition - TrackPosition) + AlbumStarts) & ')'
          ELSE
            TARGET{Prop:Text} = 'CD ' & CLIP(StatusText)
          END
        END
        Old_TitleRequired = TitleRequired
      END
    OF EVENT:CloseWindow
      SavePlayerStatus
      BREAK
    OF EVENT:Timer
      TitleRequired = False
      IF ControlPanel OR TARGET{Prop:Iconize}
        TitleRequired = True
      END
      IF NOT CDAvailable
        DO AttemptCDInitialize
        IF TitleRequired
          TARGET{Prop:Text} = 'Device Not Available'
        ELSIF Old_TitleRequired <> TitleRequired
          TARGET{Prop:Text} = 'Audio CD Player'
        END
      ELSE
        DO DetectCDStatus
        IF TitleRequired
          IF AlbumPosition <> '00:00'
            TARGET{Prop:Text} = 'CD ' & CLIP(ShortText) & '  (' & FixDisplayTime((AlbumPosition - TrackPosition) + AlbumStarts) & ')'
          ELSE
            TARGET{Prop:Text} = 'CD ' & CLIP(StatusText)
          END
        ELSIF Old_TitleRequired <> TitleRequired
          TARGET{Prop:Text} = 'Audio CD Player'
        END
      END
      Old_TitleRequired = TitleRequired
    OF Event:Moved
      IF NOT TARGET{Prop:Iconize}
        GETPOSITION(0,WindowCurrentX,WindowCurrentY,WindowWidth,WindowHeight)
      END
    END
  END
  CLOSE(CDPlayWin)

!-------------------------------------------------------------------------
InitializePlayer ROUTINE
  INISettingsFound = False
  IF GETINI('CD Player Settings','Product','','CW_CD.INI')
    INISettingsFound = True
    StayOnTop = GETINI('CD Player Settings','Stay On Top',,'CW_CD.INI')
    ControlPanel = GETINI('CD Player Settings','Control Panel',,'CW_CD.INI')
    AutoPlay = GETINI('CD Player Settings','Auto Play',,'CW_CD.INI')
    CurrentDisplayFlag = GETINI('CD Player Settings','Display Mode',1,'CW_CD.INI')
    WindowX = GETINI('CD Player Settings','Window X',,'CW_CD.INI')
    WindowY = GETINI('CD Player Settings','Window Y',,'CW_CD.INI')
  ELSE
    PUTINI('CD Player Settings','Product','Clarion for Windows CD Player Demo','CW_CD.INI')
    PUTINI('CD Player Settings','Copyright','1995, TopSpeed Corporation','CW_CD.INI')
  END

!-------------------------------------------------------------------------
DetectCDStatus ROUTINE
  IF MCIStatus('status cdaudio ready')
    CDStatus = MCIStatus()
  ELSE
    CDStatus = MCIStatus()
    IF CDStatus <> 'open'
      CDStatus = 'not ready'
    END
  END
  IF CDStatus <> Old_CDStatus
    DO ProcessOldStatus
  END
  DO ProcessStatus
  Old_CDStatus = CDStatus

!-------------------------------------------------------------------------
ProcessOldStatus ROUTINE
  CASE Old_CDStatus
  OF 'open'
    ?CDDoor{Prop:Icon} = '~SMM_CLOS.ICO'
    ?CDDoor{Prop:ToolTip} = 'Open the CD door'
    IF CDStatus <> 'not ready'
      IF MCIStatus('status cdaudio media present')
        DO EnableAccessButtons
      END
    END
  OF 'playing'
    IF CDStatus = 'stopped'
      IF NOT CDPaused AND CDPlaying
        CASE RepeatMode
        OF Repeat_None
          IF POINTER(PLTracks) = RECORDS(PLTracks)
            CDPlaying = False
          ELSE
            SelectTrack(POINTER(PLTracks)+1,CDPlaying)
          END
        OF Repeat_Track
          SelectTrack(POINTER(PLTracks),CDPlaying)
        OF Repeat_All
          SelectTrack(1,CDPlaying)
        END
      END
    ELSE
      ?CDPlayStop{Prop:Icon} = '~SMM_PLAY.ICO'
      ?CDPlayStop{Prop:ToolTip} = 'Play the current selections'
      DISABLE(?CDPause)
    END
  END
  CASE CDStatus
  OF 'not ready'
    ?CDDoor{Prop:Icon} = '~SMM_CLOS.ICO'
    ?CDDoor{Prop:ToolTip} = 'Open the CD door'
    StatusText = 'Not Ready'
    ShortText = 'Not Ready'
    DisplayTime = ''
    CurrentDisplayType = ''
    DO DisableAccessButtons
    AlbumPosition = ''
  OF 'open'
    ?CDDoor{Prop:Icon} = '~SMM_OPEN.ICO'
    ?CDDoor{Prop:ToolTip} = 'Close the CD door'
    StatusText = 'Door Open'
    ShortText = 'Door Open'
    DisplayTime = ''
    CurrentDisplayType = ''
    DO DisableAccessButtons
    AlbumPosition = ''
  OF 'playing'
    CDPlaying = True
    CDPaused = False
    ?CDPlayStop{Prop:Icon} = '~SMM_STOP.ICO'
    ?CDPlayStop{Prop:ToolTip} = 'Stop the CD Player'
    ENABLE(?CDPause)
    Old_StatusText = StatusText
    StatusText = 'Scanning Disc'
    DISPLAY(?StatusText)
    DO GetCompactDiscID
    IF NewCDLoaded
      DO InitializeNewAlbum
    END
    StatusText = Old_StatusText
    DISPLAY(?StatusText)
  OF 'stopped'
    IF Old_CDStatus = 'playing' AND CDPaused
      DO GetAndDisplayTrackStatus
      StatusText = 'Paused on track ' & CurrentTrack
      ShortText = 'Paused'
      CDPlaying = True
      ?CDPause{Prop:Icon} = '~SMM_PAU2.ICO'
      ?CDPause{Prop:ToolTip} = 'Restart the CD player'
    ELSE
      StatusText = 'Stopped'
      ShortText = 'Stopped'
      MCIStatus('seek cdaudio to start')
      ?CDPause{Prop:Icon} = '~SMM_PAUS.ICO'
      ?CDPause{Prop:ToolTip} = 'Pause the CD player'
      ?CDPlayStop{Prop:Icon} = '~SMM_PLAY.ICO'
      ?CDPlayStop{Prop:ToolTip} = 'Play the current selection(s)'
      DO EnableAccessButtons
      Old_StatusText = StatusText
      StatusText = 'Scanning Disc'
      AlbumPosition = ''
      DISPLAY(?StatusText)
      DO GetCompactDiscID
      IF NewCDLoaded OR Old_CDStatus = 'open'
        DO InitializeNewAlbum
        IF AutoPlay
          CDPlaying = True
          SelectTrack(1,CDPlaying)
        END
      END
      StatusText = Old_StatusText
      DISPLAY(?StatusText)
      DO GetAndDisplayTrackStatus
    END
  END

!-------------------------------------------------------------------------
ProcessStatus ROUTINE
  CASE CDStatus
  OF 'playing'
    DO GetAndDisplayTrackStatus
    StatusText = 'Playing Track ' & CurrentTrack
    ShortText = 'Playing ' & CurrentTrack
  END

!--------------------------------------------------------
AttemptCDInitialize ROUTINE
  CDEjectPossible = False
  IF MCIStatus('open cdaudio shareable') <> '1'
    StatusText = 'CD Player Not Available'
    TARGET{PROP:TIMER} = InactiveTimerDisplay
    DO DisableAccessButtons
  ELSE
    CDAvailable = True
    IF MCIStatus('capability cdaudio can eject')
      CDEjectPossible = True
      ENABLE(?CDDoor)
    END
    DO EnableAccessButtons
    DO DetectCDStatus
    TARGET{Prop:Timer} = ActiveTimerDisplay
  END

!--------------------------------------------------------
EnableAccessButtons ROUTINE
  ENABLE(?CDSelectPrev,?CDSelectNext)
  ENABLE(?Repeat,?Program)
  ENABLE(?Track01,?CurrentTrackText)

!--------------------------------------------------------
DisableAccessButtons ROUTINE
  DISABLE(?CDSelectPrev,?CDSelectNext)
  DISABLE(?Repeat,?Program)
  DISABLE(?Track01,?CurrentTrackText)

!--------------------------------------------------------
DisplayRepeatButton ROUTINE
  CASE RepeatMode
  OF Repeat_None
    ?Repeat{Prop:Text} = 'Repeat: None'
  OF Repeat_Track
    ?Repeat{Prop:Text} = 'Repeat: Track'
  OF Repeat_All
    ?Repeat{Prop:Text} = 'Repeat: All'
  END

!--------------------------------------------------------
DisplayRandomAccessButtons ROUTINE
  LOOP LoopCounter = 1 to 10
    ValueConstruct = (?Track01 - 1) + LoopCounter
    IF LoopCounter + (TrackMultiplier * 10) > NumberOfTracks
      HIDE(ValueConstruct,?Track10)
    ELSE
      UNHIDE(ValueConstruct,?Track10)
      ValueConstruct{Prop:Text} = (TrackMultiplier * 10) + LoopCounter
    END
  END

!--------------------------------------------------------
GetCompactDiscID ROUTINE
  NumberOfTracks = MCIStatus('status cdaudio number of tracks')
  CompactDiscID = FORMAT(NumberOfTracks,@N2)
  CompactDiscID = CLIP(CompactDiscID) & TranslateMFSTime(MCIStatus('status cdaudio length'))
  CompactDiscID = CLIP(CompactDiscID) & TranslateMFSTime(MCIStatus('status cdaudio length track 1'))
  IF NumberOfTracks > 1
    CompactDiscID = CLIP(CompactDiscID) & TranslateMFSTime(MCIStatus('status cdaudio length track 2'))
    IF NumberOfTracks > 2
      CompactDiscID = CLIP(CompactDiscID) & TranslateMFSTime(MCIStatus('status cdaudio length track 3'))
    END
  END
  NewCDLoaded = False
  IF Old_CompactDiscID <> CompactDiscID
    NewCDLoaded = True
    Old_CompactDiscID = CompactDiscID
  END

!--------------------------------------------------------
InitializeNewAlbum ROUTINE
  TrackRows = INT((NumberOfTracks - 1) / 10) + 1
  CLEAR(TrackMultiplier)
  IF TrackRows = 1
    HIDE(?TrackPlus)
  ELSE
    UNHIDE(?TrackPlus)
  END
  DO DisplayRandomAccessButtons
  CLEAR(RepeatMode)
  DO DisplayRepeatButton
  INISettingsFound = False
  FREE(TrackList)
  FREE(PlayLists)
  Playlists = 'Album Order'
  ADD(PlayLists)
  CurrentAlbumTitle = GETINI(CompactDiscID,'Title',,'CW_CD.INI')
  IF CurrentAlbumTitle
    INISettingsFound = True
    CurrentAlbumArtist = GETINI(CompactDiscID,'Artist',,'CW_CD.INI')
  ELSE
    CurrentAlbumTitle = 'New Album'
    CurrentAlbumArtist = ''
  END
  LOOP LoopCounter = 1 TO NumberOfTracks
    IF INISettingsFound
      TrackTitle = GETINI(CompactDiscID,'Track ' & LoopCounter,,'CW_CD.INI')
    ELSE
      TrackTitle = 'Track ' & LoopCounter
    END
    ADD(TrackList)
  END
  IF INISettingsFound
    LOOP LoopCounter = 1 TO GETINI(CompactDiscID,'PlayList Count',,'CW_CD.INI')
      PlayLists = GETINI(CompactDiscID,'PlayList ' & LoopCounter & ' Title',,'CW_CD.INI')
      ADD(PlayLists)
    END
  END
  GET(PlayLists,1)
  PlayList = PlayLists
  DO LoadNewPlayList
!--------------------------------------------------------
LoadNewPlayList ROUTINE
  PlayList = PlayLists
  FREE(PLTracks)
  IF POINTER(PlayLists) = 1
    LOOP LoopCounter = 1 TO NumberOfTracks
      GET(TrackList,LoopCounter)
      PLTrackNumber = LoopCounter
      PLTrackTitle = TrackTitle
      ADD(PLTracks)
    END
  ELSE
    PlayListText = GETINI(CompactDiscID,'PlayList ' & POINTER(PlayLists) - 1,,'CW_CD.INI')
    PlayListItems = PlayListArray[1]
    LOOP LoopCounter = 2 TO PlayListItems + 1
      ValueConstruct = PlayListArray[LoopCounter]
      GET(TrackList,ValueConstruct)
      PLTrackNumber = ValueConstruct
      PLTrackTitle = TrackTitle
      ADD(PLTracks)
    END
  END
  IF RECORDS(PLTracks)
    GET(PLTracks,1)
    CurrentTrackText = PLTrackTitle
  ELSE
    CurrentTrackText = ''
  END
  DISPLAY(?CurrentTrackText)
  Old_PlayList = PlayList
!--------------------------------------------------------
GetAndDisplayTrackStatus ROUTINE

  CurrentTrack = MCIStatus('status cdaudio current track')
  IF NewAlbum
    AlbumStarts = TranslateMFSTime(MCIStatus('status cdaudio start position'))
    AlbumTime = TranslateMFSTime(MCIStatus('status cdaudio length'))
    NewAlbum = False
    DO InitializeNewAlbum
  END
  IF CurrentTrack <> LastTrack
    TrackPosition = TranslateMFSTime(MCIStatus('status cdaudio position track ' & CurrentTrack))
    TrackTime = TranslateMFSTime(MCIStatus('status cdaudio length track ' & CurrentTrack))
    LastTrack = CurrentTrack
    GET(TrackList,CurrentTrack)
    CurrentTrackText = TrackTitle
    DISPLAY
  END
  AlbumPosition = TranslateMFSTime(MCIStatus('status cdaudio position'))
  AlbumPosition = AlbumPosition - AlbumStarts
  AlbumRemaining  = AlbumTime - AlbumPosition
  TrackRemaining  = TrackTime - (AlbumPosition - TrackPosition)
  EXECUTE(CurrentDisplayFlag)
    BEGIN
      DisplayTime = FixDisplayTime(AlbumPosition)
      CurrentDisplayType = 'Album Elapsed'
    END
    BEGIN
      DisplayTime = FixDisplayTime(AlbumRemaining)
      CurrentDisplayType = 'Album Remaining'
    END
    BEGIN
      DisplayTime = FixDisplayTime(AlbumTime)
      CurrentDisplayType = 'Album Total'
    END
    BEGIN
      DisplayTime = FixDisplayTime((AlbumPosition - TrackPosition) + AlbumStarts)
      CurrentDisplayType = 'Track Elapsed'
    END
    BEGIN
      DisplayTime = FixDisplayTime(TrackRemaining)
      CurrentDisplayType = 'Track Remaining'
    END
    BEGIN
      DisplayTime = FixDisplayTime(TrackTime)
      CurrentDisplayType = 'Track Total'
    END
  END

!===================================================================
StopPlayer PROCEDURE

  CODE
  MCIStatus('stop cdaudio')
  MCIStatus('seek cdaudio to start')
  CDPlaying = False
  CDPaused = False

!===================================================================
PausePlayer PROCEDURE

  CODE
  IF CDPaused
    MCIStatus('play cdaudio')
    CDPaused = False
  ELSE
    MCIStatus('pause cdaudio')
    CDPaused = True
  END

!===================================================================
SelectTrack PROCEDURE(CurrentPLTrack,PlayThisSelection)
NextStop         LONG

  CODE
  IF CurrentPLTrack > RECORDS(PLTracks)
    GET(PLTracks,1)
  ELSIF CurrentPLTrack < 1
    GET(PLTracks,RECORDS(PLTracks))
  ELSE
    GET(PLTracks,CurrentPLTrack)
  END
  IF PlayThisSelection
    MCIStatus('set cdaudio time format tmsf')
    IF POINTER(PlayLists) = 1 OR PLTrackNumber = RECORDS(Tracklist)
      MCIStatus('play cdaudio from ' & PLTrackNumber)
    ELSE
      NextStop = PLTrackNumber + 1
      MCIStatus('play cdaudio from ' & PLTrackNumber & ' to ' & NextStop)
    END
    MCIStatus('set cdaudio time format msf')
    CDPlaying = True
    CDPaused = False
  END
  CurrentTrackText = PLTrackTitle
!--------------------------------------------------------
FixDisplayTime FUNCTION(InputTime)

ConstructTime       GROUP,PRE
ConstructHours        STRING(@P##:P)
ReturnGroup           GROUP,PRE
ConstructMinutes        STRING(@P##:P)
ConstructSeconds        STRING(@P##P)
                      END
                    END
NumberOfHours       LONG
  CODE
  ConstructTime = FORMAT(InputTime,@T4)
  ConstructMinutes = ConstructMinutes + (ConstructHours * 60)
  RETURN(ReturnGroup)

!===================================================================
TranslateMFSTime FUNCTION(InputString)

ConstructTime       GROUP,PRE
ConstructHours        STRING(@P##:P)
ConstructMinutes      STRING(@P##:P)
ConstructSeconds      STRING(@P##P)
                    END

msfTimeStamp        GROUP,PRE
msfStampMinutes       STRING(@P##:P)
msfStampSeconds       STRING(@P##:P)
msfStampFrames        STRING(@P##P)
                    END

  CODE
  msfTimeStamp = InputString
  IF msfStampMinutes > 59
    ConstructHours = 1
    ConstructMinutes = msfStampMinutes - 60
  ELSE
    ConstructHours = 0
    ConstructMinutes = msfStampMinutes
  END
  ConstructSeconds = msfStampSeconds
  RETURN(DEFORMAT(ConstructTime,@T4))
!===================================================================
MCIStatus FUNCTION(MCIStatusRequest)

MCIRequestValue     CSTRING(100)
MCIReturnValue      CSTRING(100)
MCIErrorString      STRING(100)

MCIErrorNotReady    EQUATE(291)

  CODE
  IF OMITTED(1)
    MCIRequestValue = 'status cdaudio mode'
  ELSE
    MCIRequestValue = MCIStatusRequest
  END
  CLEAR(MCIErrorString)
  MCIErrorString = MCISendString(MCIRequestValue,MCIReturnValue,128,0)
  IF MCIErrorString <> '0'
    IF MCIErrorString = '265'
      RETURN('1')
    ELSE
      RETURN(MCIErrorString)
    END
  ELSE
    CASE MCIReturnValue
    OF 'true'
      RETURN('1')
    OF 'false'
      RETURN('')
    OF '1'
    OROF '2'
      RETURN('1')
    ELSE
      RETURN(MCIReturnValue)
    END
  END

!===================================================================
EditPlayList FUNCTION
CurrentSelection LONG

HoldPlayLists   QUEUE,PRE
HoldPlayListName  STRING(MaximumTextLength)
HoldPlayListArray STRING(2),DIM(100)
HoldPlayListText  STRING(200),OVER(HoldPlayListArray)
                END

PlayListEditQueue QUEUE,PRE
PlayListTrackName   STRING(MaximumTextLength)
PlayListTrackNumber LONG
                  END

EditPlayListName  STRING(MaximumTextLength)
PlaylistCount     LONG
EditCompleted     LONG
EditWindow WINDOW('Edit an Album''s Playlist'),AT(,,332,230),FONT('MS Sans Serif',8,,FONT:regular),STATUS, |
         GRAY
       SHEET,AT(6,5,319,201),USE(?Sheet1)
         TAB('Album Properties'),USE(?Tab1)
           GROUP('&Artist'),AT(15,22,148,24),BOXED
             ENTRY(@S60),AT(21,32,137,12),TIP('The name of the artist'),USE(CurrentAlbumArtist),DROPID('Move Track'),MSG('Enter the name of the album''s artist here.')
           END
           GROUP('&Title'),AT(15,48,148,24),USE(?Group2),BOXED
             ENTRY(@s60),AT(21,58),TIP('The title of the album'),USE(CurrentAlbumTitle),DROPID('Move Track'),MSG('Enter the title of the album here')
           END
           LIST,AT(15,74,148,108),TIP('The music selections on the album'),USE(?TrackList),SKIP,FORMAT('240L@S60@'), |
               FROM(TrackList),DRAGID('Add Track'),DROPID('Move Track')
           ENTRY(@s60),AT(15,186,148,12),TIP('Edit a track''s title'),ALRT(UpKey),ALRT(DownKey),ALRT(PgUpKey), |
               ALRT(PgDnKey),ALRT(CtrlPgUp),ALRT(CtrlPgDn),USE(TrackTitle),DROPID('Move Track'),MSG('Enter the title of the track.  Use the cursor keys to select new tracks to edit.')
           GROUP('&Playlist'),AT(171,22,149,47),USE(?Group3),BOXED
             LIST,AT(177,32,137,12),TIP('Edit the name of a customized playlist'),USE(EditPlayListName), |
                 FORMAT('240L@s60@'),DROP(5),FROM(HoldPlayLists),DROPID('Move Track'),MSG('Select a new playlist to edit')
           END
           LIST,AT(171,74,149,124),TIP('The music selections of a playlist'),USE(?PlayListEditQueue), |
               FORMAT('240L@S60@'),FROM(PlayListEditQueue),DRAGID('Move Track'),DROPID('Add Track'),DROPID('Move Track'),MSG('Drag tracks to the playlist to add them.  Drag tracks from the playlist to remove them.')
           BUTTON('&New'),AT(177,49,39,12),TIP('Add a customized playlist'),KEY(InsertKey),USE(?NewPlayList), |
               DROPID('Move Track'),MSG('Add a new playlist')
           BUTTON('&Edit'),AT(226,49,39,12),TIP('Edit the name of a customized playlist'),USE(?EditPlayList), |
               DROPID('Move Track'),MSG('Edit the current playlist''s name')
           BUTTON('&Remove'),AT(275,49,39,12),TIP('Remove a customized playlist'),KEY(DeleteKey),USE(?DeletePlayList), |
               DROPID('Move Track'),MSG('Remove a playlist')
         END
       END
       BUTTON('OK'),AT(199,210,40,14),TIP('Accept your changes and return to the player'),USE(?OK),DEFAULT, |
           DROPID('Move Track'),MSG('Accept changes and exit')
       BUTTON('&Cancel'),AT(243,210,40,14),TIP('Cancel your changes and return to the player'),USE(?Cancel), |
           DROPID('Move Track'),MSG('Cancel changes and exit')
       BUTTON('&Apply'),AT(287,210,40,14),TIP('Apply your changes and keep editing'),USE(?Apply),DROPID('Move Track'),MSG('Apply changes and keep editing')
       REGION,AT(0,0,333,230),USE(?TrashCan),FULL,DROPID('Move Track')
     END
CurrentWindow LONG
  CODE
  EditCompleted = False
  OPEN(EditWindow)
  GET(TrackList,1)
  FREE(PlayListEditQueue)
  FREE(HoldPlayLists)
  PlaylistCount = GETINI(CompactDiscID,'PlayList Count',,'CW_CD.INI')
  LOOP LoopCounter = 1 TO PlaylistCount
    HoldPlayListName = GETINI(CompactDiscID,'PlayList ' & LoopCounter & ' Title',,'CW_CD.INI')
    HoldPlayListText = GETINI(CompactDiscID,'PlayList ' & LoopCounter,,'CW_CD.INI')
    ADD(HoldPlayLists)
  END
  IF NOT RECORDS(HoldPlayLists)
    DISABLE(?EditPlayListName,?PlayListEditQueue)
    DISABLE(?EditPlayList,?DeletePlayList)
    CLEAR(HoldPlayLists)
  ELSE
    GET(HoldPlayLists,1)
    ?EditPlayListName{Prop:Selected} = 1
    DO LoadEditPlayList
    EditPlayListName = HoldPlayListName
  END
  ?TrackList{Prop:Selected} = 1
  ACCEPT
    IF EVENT() = Event:Drop AND DROPID() = 'Move Track'
      IF FIELD() = ?PlayListEditQueue
        CurrentSelection = ?PlayListEditQueue{PropList:MouseUpRow}
        DELETE(PlayListEditQueue)
        ADD(PlayListEditQueue,CurrentSelection)
      ELSE
        DELETE(PlayListEditQueue)
      END
    END
    CASE ACCEPTED()
    OF ?Apply
      DO ApplyChanges
    OF ?OK
      DO ApplyChanges
      POST(Event:CloseWindow)
    OF ?Cancel
      POST(Event:CloseWindow)
    OF ?NewPlayList
      DO SaveEditPlayList
      HoldPlayListName = EditPlayListTitle('')
      IF HoldPlayListName
        HoldPlayListText = ''
        ADD(HoldPlayLists)
        DO LoadEditPlayList
        ENABLE(?EditPlayListName,?PlayListEditQueue)
        ENABLE(?EditPlayList,?DeletePlayList)
        EditPlayListName = HoldPlayListName
        DISPLAY
      END
    OF ?EditPlayList
      HoldPlayListName = EditPlayListTitle(HoldPlayListName)
      PUT(HoldPlayLists)
      EditPlayListName = HoldPlayListName
      DISPLAY
    OF ?DeletePlayList
      IF MESSAGE('Are you sure you want to delete this play list?','Confirm Deletion',ICON:Question,Button:Yes+Button:No,Button:No) = Button:Yes
        DELETE(HoldPlayLists)
        IF RECORDS(HoldPlayLists)
          GET(HoldPlayLists,1)
          DO LoadEditPlayList
          EditPlayListName = HoldPlayListName
          ?EditPlayListName{Prop:Selected} = 1
        ELSE
          EditPlayListName = ''
          FREE(PlayListEditQueue)
          DISABLE(?EditPlayListName,?PlayListEditQueue)
          DISABLE(?EditPlayList,?DeletePlayList)
          CLEAR(HoldPlayLists)
        END
        DISPLAY
      END
    OF ?EditPlayListName
      DO SaveEditPlayList
      GET(HoldPlayLists,CHOICE(?EditPlayListName))
      DO LoadEditPlayList
      DISPLAY
    END
    CASE FIELD()
    OF ?PlayListEditQueue
      CASE EVENT()
      OF Event:DROP
        IF DROPID() = 'Add Track'
          PlayListTrackName = TrackTitle
          PlayListTrackNumber = CHOICE(?TrackList)
          ADD(PlayListEditQueue)
        END
      OF EVENT:Drag
        GET(PlayListEditQueue,CHOICE(?PlayListEditQueue))
      END
    OF ?TrackList
      CASE EVENT()
      OF Event:NewSelection
        GET(TrackList,CHOICE(?TrackList))
        SELECT(?TrackTitle)
        DISPLAY(?TrackTitle)
      OF EVENT:DRAG
        GET(TrackList,CHOICE(?TrackList))
      END
    OF ?TrackTitle
      CASE EVENT()
      OF Event:Accepted
        UPDATE(?TrackTitle)
        PUT(TrackList)
        DISPLAY(?TrackList)
      OF Event:AlertKey
        CurrentSelection = ?TrackList{Prop:Selected}
        UPDATE(?TrackTitle)
        CASE KEYCODE()
        OF UpKey
          PUT(TrackList)
          IF CurrentSelection = 0
            ?TrackList{Prop:Selected} = RECORDS(Tracklist)
          ELSE
            ?TrackList{Prop:Selected} = CurrentSelection - 1
          END
          POST(Event:NewSelection,?TrackList)
        OF DownKey
          PUT(TrackList)
          IF CurrentSelection = RECORDS(TrackList)
            ?TrackList{Prop:Selected} = 1
          ELSE
            ?TrackList{Prop:Selected} = CurrentSelection + 1
          END
          POST(Event:NewSelection,?TrackList)
        OF PgUpKey
          PUT(TrackList)
          ?TrackList{Prop:Selected} = CurrentSelection - 15
          POST(Event:NewSelection,?TrackList)
        OF PgDnKey
          PUT(TrackList)
          ?TrackList{Prop:Selected} = CurrentSelection + 15
          POST(Event:NewSelection,?TrackList)
        OF CtrlHome
        OROF CtrlPgUp
          PUT(TrackList)
          ?TrackList{Prop:Selected} = 1
          POST(Event:NewSelection,?TrackList)
        OF CtrlEnd
        OROF CtrlPgDn
          PUT(TrackList)
          ?TrackList{Prop:Selected} = RECORDS(TrackList)
          POST(Event:NewSelection,?TrackList)
        END
      END
    END
  END
  RETURN(EditCompleted)
!----------------------------------------------------------
ApplyChanges ROUTINE
  DO SaveEditPlayList
  PUTINI(CompactDiscID,'Title',CurrentAlbumTitle,'CW_CD.INI')
  PUTINI(CompactDiscID,'Artist',CurrentAlbumArtist,'CW_CD.INI')
  LOOP LoopCounter = 1 TO NumberOfTracks
    GET(TrackList,LoopCounter)
    PUTINI(CompactDiscID,'Track ' & LoopCounter,TrackTitle,'CW_CD.INI')
  END
  PUTINI(CompactDiscID,'PlayList Count',RECORDS(HoldPlayLists),'CW_CD.INI')
  LOOP LoopCounter = 1 TO RECORDS(HoldPlayLists)
    GET(HoldPlayLists,LoopCounter)
    PUTINI(CompactDiscID,'PlayList ' & LoopCounter & ' Title',HoldPlayListName,'CW_CD.INI')
    PUTINI(CompactDiscID,'PlayList ' & LoopCounter,HoldPlayListText,'CW_CD.INI')
  END
  LOOP LoopCounter = RECORDS(HoldPlayLists) + 1 TO PlayListCount
    PUTINI(CompactDiscID,'PlayList ' & LoopCounter & ' Title',,'CW_CD.INI')
    PUTINI(CompactDiscID,'PlayList ' & LoopCounter,,'CW_CD.INI')
  END
  EditCompleted = True

!-------------------------------------------------
LoadEditPlayList ROUTINE

  FREE(PlayListEditQueue)
  CurrentSelection = HoldPlayListArray[1]
  LOOP LoopCounter = 2 TO CurrentSelection + 1
    PlayListTrackNumber = HoldPlayListArray[LoopCounter]
    IF NOT PlayListTrackNumber
      BREAK
    END
    GET(TrackList,PlayListTrackNumber)
    PlayListTrackName = TrackTitle
    ADD(PlayListEditQueue)
  END
!-------------------------------------------------
SaveEditPlayList ROUTINE

  HoldPlayListArray[1] = RECORDS(PlayListEditQueue)
  LOOP LoopCounter = 1 TO HoldPlayListArray[1]
    GET(PlayListEditQueue,LoopCounter)
    HoldPlayListArray[LoopCounter + 1] = FORMAT(PlayListTrackNumber,@N2)
  END
  PUT(HoldPlayLists)

!===================================================================
EditPlayListTitle FUNCTION(PlayListTitle)

EditedTitle STRING(60)
ReturnValue STRING(60)

EditWindow WINDOW('Edit Playlist Title'),AT(,,188,45),FONT('MS Sans Serif',8,,FONT:regular),GRAY
       PROMPT('Title:'),AT(6,9)
       ENTRY(@s60),AT(39,6),USE(EditedTitle),REQ,TIP('The name of the playlist')
       BUTTON('OK'),AT(95,22,40,14),USE(?OK),DEFAULT,REQ,TIP('Accept this playlist name')
       BUTTON('&Cancel'),AT(139,22,40,14),USE(?Cancel),STD(STD:Close),TIP('Cancel changes to the playlist name')
     END
  CODE
  EditedTitle = PlayListTitle
  ReturnValue = PlayListTitle
  OPEN(EditWindow)
  IF NOT EditedTitle
    TARGET{Prop:Text} = 'New Playlist Title'
  END
  ACCEPT
    CASE ACCEPTED()
    OF ?OK
      UPDATE()
      ReturnValue = EditedTitle
      POST(Event:CloseWindow)
    OF ?Cancel
      POST(Event:CloseWindow)
    END
  END
  RETURN(ReturnValue)

!===================================================================
AboutCDPlayer PROCEDURE
AboutWindow WINDOW,AT(,,330,120),CENTER,GRAY
       STRING('The Clarion for Windows Compact Disc Player Example'),AT(37,7,248,16),FONT('Arial',14,,FONT:regular), |
           CENTER
       STRING('A hand-coded example, using Windows API calls to provide an interface to the'),AT(31,31,259,10), |
           CENTER
       STRING('Windows (Media Control Interface).  '),AT(101,40,120,10),CENTER
       STRING('Based on code provided by Larry Teames, a member of Team TopSpeed.'),AT(37,55,247,10), |
           CENTER
       STRING('The complete code for this application is included as part of Clarion for Window' &|
           's version 1.5.'),AT(15,73,307,10),USE(?String5)
       STRING('The total number of executable lines of code is less than 850.'),AT(20,82,281,10),CENTER
       BUTTON('OK'),AT(145,96),USE(?Button1),STD(STD:Close),DEFAULT
     END
  CODE
  OPEN(AboutWindow)
  ACCEPT
  END
!===================================================================
SavePlayerStatus PROCEDURE
  CODE
  PUTINI('CD Player Settings','Window X',WindowCurrentX,'CW_CD.INI')
  PUTINI('CD Player Settings','Window Y',WindowCurrentY,'CW_CD.INI')
  PUTINI('CD Player Settings','Stay On Top',StayOnTop,'CW_CD.INI')
  PUTINI('CD Player Settings','Control Panel',ControlPanel,'CW_CD.INI')
  PUTINI('CD Player Settings','Auto Play',AutoPlay,'CW_CD.INI')
  PUTINI('CD Player Settings','Display Mode',CurrentDisplayFlag,'CW_CD.INI')

!===================================================================
AppWindowProc FUNCTION(MyhWnd,usMsg,WParam,IParam)

    CODE
    CASE usMsg
    OF WM_QUERYENDSESSION
      RETURN(True)
    OF WM_ENDSESSION
      SavePlayerStatus
      RETURN(True)
    END
    RETURN(CallWindowProc(CDPlayerWindow,MyhWnd,usMsg,wParam,IParam))